IDEA - автоматически генерировать POJO

IntelliJ IDEA

1. maven-зависимости

springboot2、spring-data-jpa、lombok

использоватьspring-data-jpaКогда нам не нужно создавать файлы, связанные с картографом, нам нужно только автоматически генерировать классы POJO для повышения эффективности разработки.Вот краткое изложение того, как использовать IDEA для автоматического создания POJO.

2. Шаги

2.1.Подключение к базе данных в IDEA



2.2. Выбор таблиц базы данных


2.3. Измените файл конфигурации groovy


Выполните шаги, описанные выше, чтобы персонализировать файл конфигурации:

1. Обратите внимание на изменение имени пакета packageName
2. Добавьте необходимые аннотации

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.text.DateFormat
import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
packageName = "fastcloud.management.beans.pojo;"  //这里要换成自己项目 实体的包路径
typeMapping = [
        (~/(?i)int/)                      : "Integer",  //数据库类型和Jave类型映射关系
        (~/(?i)float|double|decimal|real/): "Double",
        (~/(?i)bool|boolean/)             : "Boolean",
        (~/(?i)datetime|timestamp/)       : "java.util.Date",
        (~/(?i)date/)                     : "java.sql.Date",
        (~/(?i)time/)                     : "java.sql.Time",
        (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    new File(dir, className + ".java").withPrintWriter("utf-8") { out -> generate(out, table, className, fields) }
}

def generate(out, table, className, fields) {
    def tableName = table.getName()
    out.println "package $packageName"
    out.println ""
    out.println "import lombok.*;"
    out.println "import fastcloud.management.base.BaseEntity;" // 这里自定义需要引入的包
    out.println "import lombok.experimental.Accessors;"
    out.println ""
    out.println "import javax.persistence.*;"
    out.println ""
    out.println "/**"
    out.println " * @author wcy-auto"
    out.println " **/"
    out.println "@Data"
    out.println "@NoArgsConstructor"
    out.println "@AllArgsConstructor"
    out.println "@Accessors(chain = true)"
    out.println "@ToString(callSuper = true)"
    out.println "@EqualsAndHashCode(callSuper = true)"
    out.println "@Entity"
    out.println "@Table(name = \"$tableName\")"
    out.println "public class $className extends BaseEntity {"
    out.println ""
    // 这里如果需要生成id字段需要打开
    /*if ((tableName + "_id").equalsIgnoreCase(fields[0].colum) || "id".equalsIgnoreCase(fields[0].colum)) {
        out.println "    @Id"
        out.println "    @GeneratedValue(strategy=GenerationType.IDENTITY)"
    }*/
    fields.each() {
        if (it.name != "id" && it.name != "createTime" && it.name != "updateTime") {
            if (it.comment != "" && it.comment != null) {
                out.println "    /**"
                out.println "      * ${it.comment}"
                out.println "      **/"
            }
            if (it.annos != "") out.println "  ${it.annos}"
            if (it.colum != it.name) {
                out.println "    @Column(name = \"${it.colum}\")"
            }

            out.println "    private ${it.type} ${it.name};"
            out.println ""
        }
    }
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        fields += [[
                           name   : javaName(col.getName(), false),
                           colum  : col.getName(),
                           type   : typeStr,
                           comment: col.getComment(),
                           annos  : ""]]
    }
}

def javaName(str, capitalize) {
    def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
            .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_").replaceAll(/_/, "")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

2.4. Генерация POJO


Затем выберите целевую папку для создания.Сгенерированный POJO выглядит следующим образом:


package com.zyzh.zz.trade.config;

import lombok.*;
import javax.persistence.*;

/*** @author wcy-auto**/
@NoArgsConstructor
@AllArgsConstructor
@Getter
@Builder
@ToString
@Entity
@Table(name = "dept")
public class Dept extends BaseEntity {
    /*** 上级部门ID**/
    @Column(name = "parent_id")
    private Integer parentId;
    /*** 部门名称**/
    private String name;
    /*** 1 - 正常，0 - 删除**/
    @Column(name = "del_flag")
    private Integer delFlag;
}


Категории